Math 307 - Winter 2024

Sunday, March 17, 2024

I post some useful calculations related to the Cesaro fractal in Problem 4 on Assignment 2. The construction of the Cesaro fractal is similar to the construction of the Koch snowflake that we did in class, see the notebook 20240315_A2P4_Koch_snow.nb in our shared Dropbox directory Dropbox\307_Files\2024. But, since the Cesaro fractal contains a "sawtooth" which depends on the angle, which I named $\alpha$, to determine the locations of points which form the "sawtooth", I needed to use trigonometry. See the handwritten notes below.

Below is the Mathematica code which follows the same logic that we used in the construction of the Koch snowflake. The main difference in the code below is that, in addition to two points as variables, the function below also depends on the angle $\alpha$, which, in the code, I call al.
```
Clear[CesaroLi,al];
CesaroLi[{pA_, pB_},
  al_] := {pA, (1 - 1/(2 + 2 Sin[al/2])) pA + 1/(2 + 2 Sin[al/2]) pB,
  1/2 pA + 1/2 pB +
   Cos[al/2] /(2 + 2 Sin[al/2]) {{0, -1}, {1, 0}} . (pB - pA),
  1/(2 + 2 Sin[al/2]) pA + (1 - 1/(2 + 2 Sin[al/2])) pB, pB}
```
Always test your commands with specific values.
```
CesaroLi[{{-3, 0}, {3, 0}}, Pi/3]
```
And with Manipulate[] as appropriate.
```
Manipulate[Graphics[{
   {Line[CesaroLi[{{-3, 0}, {3, 0}}, al]]}
   },
  PlotRange -> {{-4, 4}, {-1, 4}}
  ], {{al, Pi/3}, 0, Pi}]
```
The rest of the construction of the Cesaro fractal should be analogous to the construction of the Koch snowflake presented in the notebook 20240315_A2P4_Koch_snow.nb in our shared Dropbox directory Dropbox\307_Files\2024.

The above Mathematica commands you can copy-paste directly into a Mathematica notebook. And, for your convenience, I also saved them in the notebook 20240317_A2P4_Cesaro.nb in our shared Dropbox directory Dropbox\307_Files\2024.

Friday, March 15, 2024

In the first part of Problem 4 on Assignment 2 you are asked to create a function that would produce iterations of the quadratic type 2 curve. In the first picture below I show the 0th iteration in blue and the 1st iteration in red. I emphasize the points that are used. You do not need to do this on your plots. In the second picture below I show the 1st iteration in blue and the 2nd iteration in red. The large picture is the fourth iteration of the quadratic type 2 curve.

In the second part of Problem 4 you are ask you to create a function that would produce iterations of the Cesaro fractal which depends on angle $\alpha$. The four pictures below show the 0th, 1st, 2nd and the 3rd iteration of the Cesaro fractal with the small angle $\alpha = \pi/16$.

Below is an animated gif file that cycles through the 1st, 2nd, 3rd, 4th, 5th and the 6th iteration of the Cesaro fractal and, within each of the iterations cycles through all the angles starting from $\pi$, proceeding towards $0$ and then back to $\pi$ in steps of $\pi/50$. The animation starts by the first iteration and cycles through angles from $\pi$ to $0$ and back to $\pi$. This is repeated for 2nd, 3rd, 4th 5th and 6th iteration. For each iteration there are 101 pictures.

Place the cursor over the image to start the animation.

Friday, March 8, 2024

The notebook 20240308_A2P2_cycloid.nb in our shared Dropbox directory Dropbox\307_Files\2024 contains what we discussed today. This file relates to Problem 2 on Assignment 2. In this file, I demonstrated how to get an illusion of motion of a simple mathematical wheel (a unit circle) using Manipulate[] and spokes.
We previously discussed a highly useful concept in Mathematica: the pure function. In the code in 20240308_A2P2_cycloid.nb, pay attention to occurrences of pure functions in action to create many lines or many points.

Pure Function. In earlier exercises, we often assigned a name to a function for further use. However, this approach is not always practical. Mathematica allows us to use functions as if they were named without actually naming them. For example, the square function is not explicitly named in Mathematica, but we can calculate the square of 7 by writing (#^2)&[7]. In this case, we use (#^2)& as a reference to the square function. Instead of explicitly naming the argument, we use a placeholder #, and we conclude the definition with &.

The full potential of a pure function is realized when combined with the Map[] command. For instance, Map[(#^2)&,{a,b,c}] yields {a^2,b^2,c^2}. Thus, Map[] applies the specified function to each member of the given list. An alternative shortcut form for Map[] is /@. Using this shortcut, the previous example becomes (#^2)&/@{a,b,c}. This approach is extremely beneficial when dealing with complex functions and large lists containing hundreds of entries.
In Problem 2 on Assignment 2 you are asked to explore two famous curves cycloid and cardioid. First we discuss the cycloid.
Wikipedia's definition of a Cycoid is: A cycloid is the curve traced by a point on the rim of a circular wheel as the wheel rolls along a straight line without slipping. One could demonstrate a cycloid in a dark room by attaching a small light to a rolling wheel and taking a long exposure photography of the motion. This is what American photographer Berenice Abbott did to create her photograph Cycloid:

You can read more about Berenice Abbott and her art at MoCP and Mount Holyoke College
In this item I will illustrate the derivation of the parametric equations for the cycloid which you need to implement in the animations in Mathematica. In the following derivation the vectors $\mathbf{i}$ and $\mathbf{j}$ are the unit coordinate vectors $\displaystyle \left[\begin{array}{c} 1 \\ 0 \end{array} \right]$ and $\displaystyle \left[\begin{array}{c} 0 \\ 1 \end{array} \right]$, respectively. In Mathematica notation the vector $\mathbf{i}$ is the pair {1,0} and the vector $\mathbf{j}$ is the pair {0,1}.
Let $t\in [0,\pi].$ The position vector of the gray center of the circle in the above pictures is \[ t \, \mathbf{i} + \mathbf{j}. \] If the unit circle was positioned at the origin, then the position vector of the red point on the unit circle would be \[ \bigl(\cos(-t -\pi/2) \bigr) \, \mathbf{i} + \bigl(\sin(-t -\pi/2) \bigr) \mathbf{j} = - (\sin t ) \, \mathbf{i} - (\cos t ) \mathbf{j}. \] Consequently, the position vector of the red point on the unit circle in the above pictures is \[ \bigl( t - \sin t \bigr) \, \mathbf{i} + \bigl(1 - \cos t \bigr) \mathbf{j}. \] In Mathematica notation the vector $\mathbf{i}$ is the pair {1,0} and the vector $\mathbf{j}$ is the pair {0,1}. Thus, the parametric equations of the cycloid in Mathematica notation is (t - Sin[t]) {1,0} + (1 - Cos[t]) {0,1} = {t - Sin[t] , 1 - Cos[t] } The following animation might help you to understand the above derivation.
Place the cursor over the image to start the animation.
In the first part of Problem 2 I ask you to reproduce the following three animations.
Place the cursor over the image to start the animation.

Place the cursor over the image to start the animation.

Place the cursor over the image to start the animation.

In the second part of Problem 2 I ask you to explore the Cardioid.

Here is a derivation of the equation of a cardioid.

Click through several helpful images.

The origin $O = (0,0)$ of the coordinate system is the gray point. Denote by $C$ the black point in the picture.
Both circles in the picture are unit circles, the gray one centered at $O,$ the black one centered at $C.$
The angle at the gray point marked by the blue arc between the green and the blue point measures $t$ radians. That is, the length of this blue arc is $t.$
There are two other angles in the picture which also measure $t$ radians: the angle marked by the blue arc between the blue and the red point and the angle marked by the black arc between the blue point and the purple point.
The green point is $(1,0),$ the blue point is $(\cos t, \sin t),$ the black point $C$ is $(2\cos t, 2\sin t),$ the purple point is $(2\cos t-1, 2\sin t).$
The goal is to determine the coordinates of the red point.
Denote by $\mathbf{a}$ the unit vector whose tail is the black point and whose head is the red point. Based on the previous items we have \begin{align*} \mathbf{a} & = \bigl(\cos( \pi+2 t ) \bigr) \mathbf{i} + \bigl(\sin( \pi+2 t ) \bigr) \mathbf{j} \\ & = -\bigl(\cos(2 t ) \bigr) \mathbf{i} - \bigl(\sin(2 t ) \bigr) \mathbf{j}. \end{align*}
Denote by $\mathbf{c}$ the position vector of the black point. Then the position vector of the red point is \[ \mathbf{c} + \mathbf{a} = \bigl( 2 \cos t - \cos(2 t ) \bigr) \mathbf{i} + \bigl(2 \sin t - \sin(2 t ) \bigr) \mathbf{j}. \]
Thus the parametric equations for this cardioid are \begin{align*} x & = 2 \cos t - \cos(2 t ) \\ y & = 2 \sin t - \sin(2 t ) \end{align*}

In the Cardioid part of Problem 2 on Assignment 2 you need to reproduce two pictures from Wikipidia's Cardioid page I made an animation that unifies these two pictures. You should be able to produce something like the animation below. If not, you can present one animation and one picture.
Place the cursor over the image to start the animation.
Once you have figured out how to construct a cardioid, you should be able to construct Generalized Cardioids. In this part of Problem 2 you are asked to produce some of the generalized cardioids as shown in the animations below. These animated gif files are large. On a slow internet connection it takes a while for them to load.
Below is the cardioid generated by a wheel with radius 1/2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 1/3 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 3/2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
For completeness, I post four more generalized cardioids; this is for the optional third part of Problem 2. The animations below are large. On a slow internet connection it takes a while for them to load.
Below is the cardioid generated by a wheel with radius 1/2 rolling inside of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 1/3 rolling inside of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 2 rolling "inside" of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 3/2 rolling "inside" of a circle with radius 1.
Place the cursor over the image to start the animation.

Wednesday, March 6, 2024

Inspired by Problem 3 on Assignment 1, I decided to try a more general problem:

Five points in the plane (under some conditions) determine a conic section uniquely.

How to illustrate this fact in Mathematica? I asked ChatGPT to write code for me. But, this time, ChatGPT's code did not work. I studied ChatGPT's code and start seeing a solution there. Below is a "bare bones" code for this problem

Manipulate[
 Module[{mat, conic},
  mat = Prepend[{#[[1]]^2, #[[1]] #[[2]], #[[2]]^2, #[[1]], #[[2]],
       1} & /@ {pA, pB, pC, pD, pE}, {x^2, x y, y^2, x, y, 1}];
  conic = Det[mat];
  ContourPlot[conic == 0, {x, -5, 5}, {y, -5, 5},
   PlotPoints -> {100, 100},
   ContourStyle -> {Thickness[0.006], RGBColor[0, 0, 0.5]},
   PlotRange -> {{-5, 5}, {-5, 5}}, AspectRatio -> Automatic,
   ImageSize -> 500]],
 {{pA, {0, -3}}, {-5, -5}, {5, 5},
  Locator}, {{pB, {1, -2}}, {-5, -5}, {5, 5},
  Locator}, {{pC, {-1, -2}}, {-5, -5}, {5, 5},
  Locator}, {{pD, {-2, 1}}, {-5, -5}, {5, 5},
  Locator}, {{pE, {2, 1}}, {-5, -5}, {5, 5}, Locator}]

Below is an extended code that shows more information about the conic that is being created:

Manipulate[
 Module[{mat, conic, mins},
  mat = Prepend[{#[[1]]^2, #[[1]] #[[2]], #[[2]]^2, #[[1]], #[[2]],
       1} & /@ {pA, pB, pC, pD, pE}, {x^2, x y, y^2, x, y, 1}];
  conic = Det[mat]; mins = Map[Reverse, Minors[mat], {0, 1}][[1]];
  If[And[Abs[mins[[1]]] < 0.01, Abs[mins[[2]]] < 0.01,
    Abs[mins[[3]]] < 0.01, Abs[mins[[4]]] < 0.01,
    Abs[mins[[5]]] < 0.01],
   ContourPlot[None, {x, -5, 5}, {y, -5, 5},
    Epilog -> {Text["No conic!", {0, 4}]},
    PlotRange -> {{-5, 5}, {-5, 5}}, AspectRatio -> Automatic,
    ImageSize -> 500],
   ContourPlot[conic == 0, {x, -5, 5}, {y, -5, 5},
    PlotPoints -> {100, 100},
    ContourStyle -> {Thickness[0.01], RGBColor[0, 0, 0.5]},
    Epilog -> {If[
       Abs[Det[{{mins[[1]], mins[[2]]/2}, {mins[[2]]/2,
            mins[[3]]}}]] < 0.01, Text["Parabola", {0, 4}],
       If[Det[{{mins[[1]], mins[[2]]/2}, {mins[[2]]/2, mins[[3]]}}] >
         0.01, Text["Ellipse", {0, 4}], Text["Hyperbola", {0, 4}]]],
      Text[N[Eigenvalues[{{mins[[1]], mins[[2]]/2}, {mins[[2]]/2,
           mins[[3]]}}]], {0, 4.5}]}, PlotRange -> {{-5, 5}, {-5, 5}},
     AspectRatio -> Automatic, ImageSize -> 500]]
  ],
 {{pA, {0, -3}}, {-5, -5}, {5, 5},
  Locator}, {{pB, {1, -2}}, {-5, -5}, {5, 5},
  Locator}, {{pC, {-1, -2}}, {-5, -5}, {5, 5},
  Locator}, {{pD, {-2, 1}}, {-5, -5}, {5, 5},
  Locator}, {{pE, {2, 1}}, {-5, -5}, {5, 5}, Locator}]

A brief explanation for the code above is: A conic section in the $xy$-plane is determined by a quadratic polynomial equation in two variables: \[ a x^2+b x y+ c y^2+d x + e y + f = 0. \] The above expression is a linear combination of the followomg six functions: \[ x^2, \quad x y, \quad y^2, \quad x, \quad y, \quad 1. \] Given five points \[ (x_1,y_1), \quad (x_2,y_2), \quad (x_3,y_3), \quad (x_4,y_4), \quad (x_5,y_5), \] we make a linear combination of the functions \[ x^2, \quad x y, \quad y^2, \quad x, \quad y, \quad 1 \] that goes through the given five points by setting the following $6\times 6$ determinant equal to zero: \[ \left| \begin{array}{cccccc} x^2 & x y & y^2 & x & y & 1 \\ x_1^2 & x_1 y_1 & y_1^2 & x_1 & y_1 & 1 \\ x_2^2 & x_2 y_2 & y_2^2 & x_2 & y_2 & 1 \\ x_3^2 & x_3 y_3 & y_3^2 & x_3 & y_3 & 1 \\ x_4^2 & x_4 y_4 & y_4^2 & x_4 & y_4 & 1 \\ x_5^2 & x_5 y_5 & y_5^2 & x_5 & y_5 & 1 \\ \end{array} \right| = 0. \]
The above Manipulation[] combined with Export[] from Mathematica produced the animated png file which is shown below.

Saturday, March 2, 2024

Whether for better or worse, I am fascinated by the concept of 'funny' trigonometric functions. Personally, I believe it is for the better.
```
Fascination is a gift.
Let yourself be fascinated. 
```
So, I often look for new "funny" trigonometric functions. One idea that I explored was to combine the regular sine function and the trapezoidal sine function from Problem 1 on Assignment 1. What I mean by this is shown in the picture below. The yellow highlighted parts of the graph are from the trapezoidal sine function, and the cyan highlighted parts are from the standard sine function.

To plot the above function I used the Mathematica command Piecewise[], as follows


 Piecewise[{
   {Mod[x, 8 + 2 Pi],
    And[Mod[x, 8 + 2 Pi] >= 0, Mod[x, 8 + 2 Pi] < 1]},
   {1 + Sin[Mod[x, 8 + 2 Pi] - 1],
    And[Mod[x, 8 + 2 Pi] >= 1, Mod[x, 8 + 2 Pi] < 1 + Pi/2]},
   {2, And[Mod[x, 8 + 2 Pi] >= 1 + Pi/2, Mod[x, 8 + 2 Pi] < 3 + Pi/2]},
   {1 + Sin[Mod[x, 8 + 2 Pi] - 3],
    And[Mod[x, 8 + 2 Pi] >= 3 + Pi/2, Mod[x, 8 + 2 Pi] < 3 + Pi]},
   {(4 + Pi) - Mod[x, 8 + 2 Pi],
    And[Mod[x, 8 + 2 Pi] >= 3 + Pi, Mod[x, 8 + 2 Pi] < 5 + Pi]},
   {-1 + Sin[Mod[x, 8 + 2 Pi] - 5],
    And[Mod[x, 8 + 2 Pi] >= 5 + Pi, Mod[x, 8 + 2 Pi] < 5 + (3 Pi)/2]},
   {-2, And[Mod[x, 8 + 2 Pi] >= 5 + (3 Pi)/2,
     Mod[x, 8 + 2 Pi] < 7 + (3 Pi)/2]},
   {-1 + Sin[Mod[x, 8 + 2 Pi] - 7],
    And[Mod[x, 8 + 2 Pi] >= 7 + (3 Pi)/2,
     Mod[x, 8 + 2 Pi] < 7 + 2 Pi]},
   {Mod[x, 8 + 2 Pi] - (8 + 2 Pi),
    And[Mod[x, 8 + 2 Pi] >= 7 + 2 Pi, Mod[x, 8 + 2 Pi] < 8 + 2 Pi]}
   }]

What I soon discovered is that Piecewise[] when used in plotting complicated objects is very slow, almost unusable. There are two solutions for this problem

Find a way to define the desired function without using Piecewise[], that is by using some other already defined Mathematica functions. This is a preferred option.
Create a compiled version of the desired function by using the Mathematica command Compile[].

Since I was not able to find a simpler form for the desired function, I used Compile[] as follows


 Clear[LoSin, LoCos]; LoSin = Compile[{{x, _Real}}, Piecewise[
   {
    {Mod[x, 4 + Pi], And[Mod[x, 4 + Pi] >= 0, Mod[x, 4 + Pi] < 1/2]},
    {1/2 + 1/2 Sin[2 (Mod[x, 4 + Pi] - 1/2)],
     And[Mod[x, 4 + Pi] >= 1/2, Mod[x, 4 + Pi] < 1/2 + Pi/4]},
    {1, And[Mod[x, 4 + Pi] >= 1/2 + Pi/4,
      Mod[x, 4 + Pi] < 3/2 + Pi/4]},
    {1/2 + 1/2 Sin[2 (Mod[x, 4 + Pi] - 3/2)],
     And[Mod[x, 4 + Pi] >= 3/2 + Pi/4, Mod[x, 4 + Pi] < 3/2 + Pi/2]},
    {(4 + Pi)/2 - Mod[x, 4 + Pi],
     And[Mod[x, 4 + Pi] >= 3/2 + Pi/2, Mod[x, 4 + Pi] < 5/2 + Pi/2]},
    {-(1/2) + 1/2 Sin[2 (Mod[x, 4 + Pi] - 5/2)],
     And[Mod[x, 4 + Pi] >= 5/2 + Pi/2,
      Mod[x, 4 + Pi] < 5/2 + (3 Pi)/4]},
    {-1, And[Mod[x, 4 + Pi] >= 5/2 + (3 Pi)/4,
      Mod[x, 4 + Pi] < 7/2 + (3 Pi)/4]},
    {-(1/2) + 1/2 Sin[2 (Mod[x, 4 + Pi] - 7/2)],
     And[Mod[x, 4 + Pi] >= 7/2 + (3 Pi)/4, Mod[x, 4 + Pi] < 7/2 + Pi]},
    {Mod[x, 4 + Pi] - (4 + Pi),
     And[Mod[x, 4 + Pi] >= 7/2 + Pi, Mod[x, 4 + Pi] < 4 + Pi]}
    }]];
LoCos = Compile[{{x, _Real}}, LoSin[x + 1 + Pi/4]];

The function that I showed at the beginning of the post is in fact not a "funny" sine function since its range is $[-2,2].$ Therefore, for the definitions of the funny trigonometric functions LoSin[] and LoCos[], I scaled both dependent and independent variables of the function given at the beginning. Below are the graphs of the newly defined "funny" trigonometric functions.
As for all "funny" trigonometric functions we explore the funny unit circle
Place the cursor over the image to start the animation.
the funny sphere the funny toroid when we deal with toroids whose cross-section is not a circle it is interesting to rotate the cross-section as it makes its turn to form a twisted toroid: and the funny vase

Friday, March 1, 2024

Below I present two animations which show two ways to construct the one-third-twisted triangular toroid.

In this item, the one-third-twisted triangular toroid is constructed by a rotating equilateral triangle. The triangle is rotated by the full circle, that is the angle $2\pi$.

Place the cursor over the image to start the animation.

The code that is used for the above picture (not the animation) is below:


Show[ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[t, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[t,3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {t, 0,
   3}, {s, 0, 2 Pi}, PlotPoints -> {51, 201},
  PlotStyle -> {Opacity[0.9]}, Mesh -> False, Exclusions -> None,
  PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[0, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[0,
     3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0, 0.75], Thickness[0.006]},
  Exclusions -> None],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[1, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[1, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0.95, 0, 0], Thickness[0.006]},
  Exclusions -> None],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[2, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[2, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0.85, 0], Thickness[0.006]},
  Exclusions -> None], ImagePadding -> {{0, 0}, {0, 0}},
 Boxed -> True, BoxStyle -> {Opacity[0]}, Axes -> False,
 ImageSize -> 1000, PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}]

The above code uses the functions that we defined earlier:


Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

In this item, the one-third-twisted triangular toroid is constructed by a rotating line segment. The line segment is rotated by the three full circles, that is by the angle $6\pi$.

Place the cursor over the image to start the animation.

The code that is used for the above picture (not the animation) is below:


Show[ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[t, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[t, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {t, 0,
   1}, {s, 0, 6 Pi}, PlotPoints -> {51, 201},
  PlotStyle -> {Opacity[0.9]}, Mesh -> False, Exclusions -> None,
  PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[0, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[0, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   6 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0, 0.75], Thickness[0.006]},
  Exclusions -> None], ImagePadding -> {{0, 0}, {0, 0}},
 Boxed -> True, BoxStyle -> {Opacity[0]}, Axes -> False,
 ImageSize -> 1000, PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}]

The above code uses the functions that we defined earlier:


Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

Thursday, February 22, 2024

Today we introduced functions inspired by the trigonometric functions cosine and sine, but designed to draw regular ngons, for example equilateral triangle, square, pentagon, hexagon, heptagon, octagon, nonagon, decagon, hendecagon, dodecagon, and so on. The notebook that I created today you can find in our shared Dropbox directory \307_Files\2024\ under the name 20240222_ngons.nb.
The most important feature of the functions Cos[t] and Sin[t] is that they provide a parametrization of the unit circle. The animation below illustrates how this parametrization is obtained.
The main components of the animation are as follows
- The black circle is the unit circle.
- The values of t $\in [0,2\pi]$ are represented by orange lengths. In each scene there are three orange lengths: the horizontal length, the vertical length and the arc length on the unit circle.
- The values of Cos[t] are green horizontal line segments.
- The values of Sin[t] are blue vertical line segments.

Place the cursor over the image to start the animation.

The principle presented above is the general principle of parametric equations of curves in the plane. Given two functions (one green and one blue) of the same independent variable t, taken as the coordinates of a moving point, then, as the independent variable t changes, the point does trace a curve in the plane.
In the PNG picture below I explain the geometry that is behind the definition of NgonCos[] and NgonSin[] which I defined in class. In the PNG picture below I used the function Mod[t,1]. In class I used the equivalent expression t-Floor[t]. In fact you can check in Mathematica that
```
FullSimplify[Mod[t, 1] == t - Floor[t]]
```
The result of the preceding command is True, meaning that Mathematica recognizing the above identity as correct.

The formulas derived in the preceding item, implemented in Mathematica are as follows:


Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

The final product of this work are the graphs of the first nine regular $n$-gons inscribed in the unit circel: the equilateral triangle, the square, and the pentagon, the hexagon, the heptagon, the octagon, the nonagon, the decagon, the hendecagon, the dodecagon, see the Regular Polygon webpage at Wolfram MathWorld.

Wednesday, February 21, 2024

Below I give a short summary of the commands that we used so far with brief comments. I present only the minimal code for the functions without any options. In the file posted yesterday, I use many options to get results exactly as I want them. A nice feature of the commands that I post below is that you can copy and paste them directly to Mathematica.
- The command Plot[] is used to plot functions. Below I plot two functions, cosine and sine.
```
Plot[{Cos[x],Sin[x]}, {x,-Pi,3 Pi}]
```
- The command ParametricPlot[] is used to plot parametric curves. Below I plot the unit circle.
```
ParametricPlot[{Cos[t],Sin[t]}, {t,0,2 Pi}]
```
- The command Graphics[] is used to plot specific graphics objects. In class, we used it to plot many points, the code is Point[].
```
Graphics[
 {
  {PointSize[0.1], RGBColor[0, 0, 0], Point[{0, 0}]},
  {PointSize[0.1], RGBColor[1, 0, 0], Point[{1, 0}]},
  {PointSize[0.1], RGBColor[0, 1, 0], Point[{0, 1}]},
  {PointSize[0.1], RGBColor[1, 1, 0], Point[{1, 1}]}
  },
 Frame -> True, PlotRange -> {{-0.25, 1.25}, {-0.25, 1.25}},
 ImageSize -> 600
 ]
```
  In the command above, please notice that each point is in its own list wrapped in curly brackets (braces) {}. There are four points plotted above. Also notice that these four points are in a separate list. I placed the open brace { on a separate line and I placed the closed brace } on a separate line. After the closed brace is comma, see },, and after }, I list three options: Frame -> True, PlotRange -> {{-0.25, 1.25}, {-0.25,1.25}}, ImageSize -> 600 separated by commas.
- The command Plot3D[] is used to plot functions of two variables. Below I plot the product the cosine and the sine.
```
Plot3D[ Cos[x]*Sin[y], {x,-Pi,3 Pi}, {y,-Pi,3 Pi}]
```
- The command ParametricPlot3D[] is used to plot curves and surfaces in three dimensional space. Below I plot a cylinder.
```
ParametricPlot3D[ {Cos[t],Sin[t],z}, {t,0,2 Pi}, {z,0,3}]
```
  Below I plot a helix.
```
ParametricPlot3D[ {Cos[t],Sin[t],t/(2 Pi)}, {t,0,6 Pi}]
```

Tuesday, February 20, 2024

Today we continued reading my notebook TheBeautyOfTrigonometry.nb which you can find in the Dropbox directory 307_Files\2024 which I shared with you. Today I added few more commands to this notebook.
To access this notebook you need to read my email in which I explained how to share a Dropbox directory with me. In the same directory you can find a PDF printout of this Mathematica notebook which you can read when you do not have access to Mathematica.
If you still do not have access to the Dropbox directory 307_Files\2024 which I shared with you, I post a PDF printout of this notebook. This is a large file and it is not well formatted, but, I hope, that it can be useful for you to study Mathematica commands while you do not have access to Mathematica software.

Friday, February 16, 2024

If you want your notebook to be automatically saved every time you execute a command in Mathematica, perform these steps:
- open the menu item Edit and click Preferences;
- in Preferences, choose the menu item Advanced and click Open Option Inspector at the bottom of the Preferences window;
- choose alphabetically in Show option values;
- go to the option name: NotebookAutoSave and check the box on the right-hand side of the screen.
Today we read my notebook TheBeautyOfTrigonometry.nb which you can find in the Dropbox directory 307_Files\2024 which I shared with you. In the same directory you can find a PDF printout of this Mathematica notebook which you can read when you do not have access to Mathematica. If you still do not have access to the Dropbox directory 307_Files\2024, I post a PDF printout. This is a large file and it is not well formatted, but, I hope, that it can be useful for you to study Mathematica commands while you do not have access to Mathematica software.

Wednesday, February 14, 2024

In this part of the class we study computational software system Wolfram Mathematica. We will focus on symbolic and numerical calculations, visualization, and programming in Mathematica. But Mathematica is much more than that. To read more about Mathematica see An Elementary Introduction to the Wolfram Language.
The following question naturally arises as we start with the Mathematica portion of this class: Why learn about Mathematica? This is not an easy question. Here are some aspects of Mathematica that make it worth your attention.
- Mathematica is a powerful computational tool that can handle a wide range of mathematical problems, from basic algebra to advanced calculus and beyond.
- Unlike many other mathematical software systems, Mathematica excels in symbolic computation, allowing you to manipulate mathematical expressions and equations symbolically closely resembling mathematical structures and thinking.
- Mathematica provides sophisticated visualization capabilities, enabling you to create compelling graphical representations of your mathematical results.
- Mathematica is a high-level programming language that offers an extensive array of predefined functions, designed to simplify and streamline tasks that are commonly encountered in mathematical and technical computing. My impression is that this makes it more accessible and user-friendly compared to other mathematical software, enabling users to achieve complex objectives with greater ease.
- A lot of help is available on-line, for example Mathematica Stack Exchange, Wolfram Community and ChatGPT is quite good at offering help with Mathematica questions.
- Solving mathematical problems is easier using Mathematica. How so? If a problem involves symbolic manipulations, we can do them in Mathematica exactly; if that approach does not lead to a solution, we can perform numerical approximations, and to guide us toward the process, we can use graphical visualization.
I have enjoyed the interaction between my mind and computer since I started using computers in the early 1990s. Only recently, I encountered a beautiful visualization of the relationship between the mind and computer expressed by Steve Jobs: In an old interview, Steve Jobs explained the usefulness of computers with a beautiful image. He said: "For me, a computer has always been a bicycle for the mind." That is what ChatGPT is. And isn't that wonderful! See the Bicycle for the Mind video. Or, a longer version.
I am convinced that your mathematical learning experience will be enriched if you engage in mathematical explorations using technology.
For example, on Sunday, I encountered the following beautiful geometric fact online. Consider two squares. A vertex of a larger square is at the center of the smaller square. Whatever the position of these two squares, the area of their intersection is the same. My wording may not be good enough. But an animation is worth a thousand words. How am I to make an animation? I must use technology. Here is an animation created in Mathematica.
Place the cursor over the image to start the animation.
I should have left it as an exercise for you to figure out why what I claim in the preceding item is true. But, the solution supported by Mathematica animation might indicate why using technology can be powerful tool in communicating Mathematics.
Place the cursor over the image to start the animation.

Friday, December 22, 2023 (updated February 14, 2024)

The Mathematica part of the class will start on Tuesday, February 13, 2024 in BH 215 at 2:00 pm.
The information sheet
We will use
To get started with Mathematica see my Mathematica page. Please watch the videos that are on my Mathematica page before the first class. Watching the movies is essential for being able to organize your homework notebooks well! I will not discuss the basics of notebook structuring in class.

Winter 2024
MATH 307: Mathematical computing
with Mathematica

Branko Ćurgus

Winter 2024 MATH 307: Mathematical computing with Mathematica

Branko Ćurgus

Winter 2024
MATH 307: Mathematical computing
with Mathematica