Math 307 - Spring 2024

Friday, June 7, 2024

In Problem 2 Part (b) we explore all distinct Goldbach partitions of even integers greater than $4$. In fact, we are interested only in the count of distinct Goldbach partitions for each even integer; call this count the Goldbach length of an even number. For example, \begin{align*} 32 &= 3+29 = 13+19, \\ 34 &= 3 + 31 = 5 + 29 = 11 + 23 = 17 + 17, \\ 36 & = 5+31 = 7+29 = 13+23 = 17 + 19. \end{align*} Here are the first eighteen Goldbach lengths displayed as a Mathematica list:
{{6, 1}, {8, 1}, {10, 2}, {12, 1}, {14, 2}, {16, 2},
{18, 2}, {20,2}, {22, 3}, {24, 3}, {26, 3}, {28, 2},
{30, 3}, {32, 2}, {34, 4}, {36, 4}, {38, 2}, {40, 3}}
Below is a plot of the first sixty values of the Goldbach lengths. Reproduce the image below. Below is a plot of the first ten thousand values of the Goldbach lengths. Reproduce the image below. Below is a plot of the first fifty thousand values of the Goldbach lengths. Reproduce the image below. Below is a plot of the first five hundred thousand values of the Goldbach lengths. I wanted to create my own version of the picture from Wikipedia. If you can, reproduce the image below.
In Problem 2 Part (b-4) we explore:
- the Goldbach lengths of the even numbers which are divisible by $6$ (colored red in the plots below)
- the Goldbach lengths of the even numbers which leave remainder $2$ when divided by $6$ (colored green in the plots below)
- the Goldbach lengths of the even numbers which leave remainder $4$ when divided by $6$ (colored blue in the plots below)
Below is a colored plot of the first sixty values of the Goldbach lengths. Reproduce the image below. Below is a colored plot of the first ten thousand values of the Goldbach lengths. Reproduce one of the two images below. Below is a colored plot of the first fifty thousand values of the Goldbach lengths. Reproduce one of the two images: one above, one below. Below is a colored plot of the first five hundred thousand values of the Goldbach lengths. I wanted to create a colored version of the picture from Wikipedia. If you can, reproduce the image below.
Clearly the pictures below indicate that the even numbers which are divisible by $6$ have more Goldbach partitions than those even numbers which are not divisible by $6.$ Also, the pictures indicate that there is no significant difference between the number of Goldbach partitions of the even numbers which leave remainder $2$ when divided by $6$ and the even numbers which leave remainder $4$ when divided by $6$. How to provide statistical evidence for these claims?
- One way is to use moving averages, see Wikipedia page for moving average. I wrote a new section about moving averages in the class file 20240607_A3P2_Goldbach_dust_moving_average.nb in our shared Dropbox directory Dropbox\307_Files\2024.
The picture below shows the moving averages (of thousand values) of the values of the Goldbach length for fifty thousand even integers.
In Problem 2 Part (c) we explore the conjecture that for every odd integer $n$ greater than $3$ there exist a nonnegative integer $a$ and a prime $p$ such that \[ n = 2 a^2 + p. \] To explore this conjecture one can use the idea which was used in Problem 2 Part (a). To get an idea how to organize While[] command to the a search, let us test the odd integer $57$. We start from $a=0$.
- $a=0$. Is $57- 2*0^2 = 57$ a prime number. No it is not.
- $a=1$. Is $57- 2*1^2 = 55$ a prime number. No it is not.
- $a=2$. Is $57- 2*2^2 = 49$ a prime number. No it is not.
- $a=3$. Is $57- 2*3^2 = 39$ a prime number. No it is not.
- $a=4$. Is $57- 2*4^2 = 25$ a prime number. No it is not.
- $a=5$. Is $57- 2*5^2 = 7$ a prime number. Yes it is.
- Stop. The conjecture is true for $57$ since $57 = 2*5^2 + 7$.
- Since all prime numbers are positive, we must have \[ 2 a^2 \lt 57. \] Thus we need to test only nonnegative integers $a$ such that \[ 0 \leq a \leq \left\lfloor \sqrt{\frac{57}{2}} \right\rfloor. \]
- If we find an odd integer $n$ greater than $3$ for which all nonnegative integers $a$ such that \[ 0 \leq a \leq \left\lfloor \sqrt{\frac{n}{2}} \right\rfloor \] result with a composite positive integer \[ n - 2 a^2, \] then the stated conjecture is not true.
Based on the analysis in the preceding item, one should organize a search, as in Problem 2 Part (a), and test several tens of thousands of odd integers greater than $3$.

Tuesday, June 4, 2024

In the first part of Problem 3 on Assignment 3 you are asked to create a function that would produce iterations of the quadratic type 2 curve. In the first picture below I show the 0th iteration in blue and the 1st iteration in red. I emphasize the points that are used. You do not need to do this on your plots. In the second picture below I show the 1st iteration in blue and the 2nd iteration in red. The large picture is the fourth iteration of the quadratic type 2 curve.

In the second part of Problem 3 you are ask you to create a function that would produce iterations of the Cesaro fractal which depends on angle $\alpha$. The four pictures below show the 0th, 1st, 2nd and the 3rd iteration of the Cesaro fractal with the small angle $\alpha = \pi/16$.

Below is an animated gif file that cycles through the 1st, 2nd, 3rd, 4th, 5th and the 6th iteration of the Cesaro fractal and, within each of the iterations cycles through all the angles starting from $\pi$, proceeding towards $0$ and then back to $\pi$ in steps of $\pi/50$. The animation starts by the first iteration and cycles through angles from $\pi$ to $0$ and back to $\pi$. This is repeated for 2nd, 3rd, 4th 5th and 6th iteration. For each iteration there are 101 pictures.

Place the cursor over the image to start the animation.

I post some useful calculations related to the Cesaro fractal in Problem 3 on Assignment 3. The construction of the Cesaro fractal is similar to the construction of the Koch snowflake that we did in class, see the notebook 20240603_Koch_snowflake.nb in our shared Dropbox directory Dropbox\307_Files\2024. But, since the Cesaro fractal contains a "sawtooth" which depends on the angle, which I named $\alpha$, to determine the locations of points which form the "sawtooth", I needed to use trigonometry. See the handwritten notes below.

Below is the Mathematica code which follows the same logic that we used in the construction of the Koch snowflake. The main difference in the code below is that, in addition to two points as variables, the function below also depends on the angle $\alpha$, which, in the code, I call al.
```
Clear[CesaroLi,al];
CesaroLi[{pA_, pB_},
  al_] := {pA, (1 - 1/(2 + 2 Sin[al/2])) pA + 1/(2 + 2 Sin[al/2]) pB,
  1/2 pA + 1/2 pB +
   Cos[al/2] /(2 + 2 Sin[al/2]) {{0, -1}, {1, 0}} . (pB - pA),
  1/(2 + 2 Sin[al/2]) pA + (1 - 1/(2 + 2 Sin[al/2])) pB, pB}
```
Always test your commands with specific values.
```
CesaroLi[{{-3, 0}, {3, 0}}, Pi/3]
```
And with Manipulate[] as appropriate.
```
Manipulate[Graphics[{
   {Line[CesaroLi[{{-3, 0}, {3, 0}}, al]]}
   },
  PlotRange -> {{-4, 4}, {-1, 4}}
  ], {{al, Pi/3}, 0, Pi}]
```
The rest of the construction of the Cesaro fractal should be analogous to the construction of the Koch snowflake presented in the notebook 20240603_Koch_snowflake.nb in our shared Dropbox directory Dropbox\307_Files\2024.

The above Mathematica commands you can copy-paste directly into a Mathematica notebook.

Friday, May 31, 2024

Assignment 3 has been posted as 2024020_A3.nb in our shared Dropbox directory Dropbox\307_Files\Assignments.
Problem 1 on Assignment 3 deals with probabilities. The notebooks 20240531_Probabilies.nb, 20240530_probabilies.nb and Probabilities.nb are related to this problem. All these notebooks are in our shared Dropbox directory Dropbox\307_Files\2024.

Tuesday, May 28, 2024

Today we talked about COLORS. I love this application of vectors so much that I wrote a webpage to celebrate it: Color Cube.
Today I created a small notebook 20240528_colors.nb in our shared Dropbox directory Dropbox\307_Files\2024. In this notebook I recreated one animation from the webpage Color Cube.
My intention was to also talk about a generalization of the convex linear combinations: given two vectors $\mathbf{u}$ and $\mathbf{v}$ the linear combination \[ (1 - t) \mathbf{u} + t \mathbf{v} \qquad \text{with} \qquad t \in [0,1], \] is called a convex linear combination of the vectors $\mathbf{u}$ and $\mathbf{v}$. It gives us all the vectors whose heads are on the line segment joining the heads of $\mathbf{u}$ and $\mathbf{v}$. If you have time, please look at the notebook 20240528_broken_line.nb in our shared Dropbox directory Dropbox\307_Files\2024 in which I show how to generalize the construction from the displayed equation to several vectors.

Saturday, May 25, 2024

On Friday, I created the notebook 20240524_A2P3_generalized_cardioid.nb in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook. This notebook relates to Problem 3 on Assignment 2. In this file, I constructed generalized cardioids and cardioids obtained by a small circle moving inside the unit circle.
Thinking about what we did related to generalized cardioids, I focused my attention to the families of circles associated with different generalized cardioids. On Wednesday, among other cardioids, I posted cardioids with the rolling circles with radiuses $1$, $1/2$ and $1/3$. Together with these cardioids I presented families of circles whose envelopes are the related cardioids. It occurred to me that it might be interesting to invent a transition between those families of circles. Below is an animation that I created showing transitions from the families of circles associated with the cardioids with the rolling circles with radiuses \[ 1, \quad \frac{1}{2}, \quad \frac{1}{3}, \quad \frac{1}{4}, \quad \frac{1}{5}, \quad \frac{1}{6}, \quad \frac{1}{7}, \quad \frac{1}{8}, \quad \frac{1}{9}, \quad \frac{1}{10}, \quad \frac{1}{11}, \quad \frac{1}{12}. \]

If the radius of the rolling circle is \[ r = \frac{1}{k} \quad \text{with} \quad k \in \bigl\{1,2,3,4,5,6,7,8,9,10,11,12 \bigr\} \] the corresponding family of circles that you see in the pictures above is given by \[ \text{center:} \ \bigl( \cos(t), \sin(t) \bigr), \quad \text{radius:} \ 2 r \left| \sin\left(\frac{t}{2 r}\right) \right|, \qquad \text{with} \quad t \in [0,2 \pi]. \] So, such a family is conveniently created in Mathematica using the following pure function
```
Circle[{ Cos[#], Sin[#] }, 2 r Abs[ Sin[ #/(2 r) ] ]  ]&/@Range[0, 2 Pi, Pi/64]
```
A complete Manipulation[] in which you can experiment with different radiuses and different number of circles in the family is as follows
```
Manipulate[Graphics[{
   {
    {AbsoluteThickness[2], AbsoluteThickness[1],
     RGBColor[0.95 {1, 1, 1}], Circle[{0, 0}, 1]}
    },
   {
    RGBColor[0.75 {1, 1, 1}], Thickness[0.002],
    Circle[{Cos[#], Sin[#]}, 2 r Abs[Sin[#/(2 r)]]] & /@
     Range[0, 2 Pi, Pi/n]
    },
   {
    {RGBColor[.5, 0, 0], AbsoluteThickness[2],
     Line[{(1 + r) Cos[#] - r Cos[(1 + 1/r) #], (1 + r) Sin[#] -
          r Sin[(1 + 1/r) #]} & /@ Range[0, 2 Pi, Pi/128]]},
    {RGBColor[.5, 0, 0], AbsoluteThickness[2],
     Line[{(1 - r) Cos[#] + r Cos[(1 - 1/r) #], (1 - r) Sin[#] +
          r Sin[(1 - 1/r) #]} & /@ Range[0, 2 Pi, Pi/128]]}
    }
   },
  AspectRatio -> Automatic, PlotRange -> {{-3.1, 1.7}, {-2.7, 2.7}},
  Frame -> False, ImageSize -> 600],
 {{r, 1}, 1/Range[1, 12], ControlPlacement -> Top,
  ControlType -> Setter}, {{n, 32}, {4, 8, 16, 32, 48, 64, 96},
  ControlPlacement -> Top, ControlType -> Setter}]
```
The animation below is 4 minutes long. It starts from the classical cardioid, transitions through each of the twelve cardioids listed above, and then loops back through all of them back to the cardioid.

Place the cursor over the image to start the animation.

A complete Manipulation[] in which you can experiment with the above transition is as follows
```
Manipulate[Graphics[
  {
   (* enveloped circles  *)

   {RGBColor[0.85 {1, 1, 0}], Thickness[0.002],
    Circle[{Cos[#], Sin[#]},
       (1 - Mod[t, 1]) 2/Floor[t] Abs[Sin[(Floor[t] #)/2]] +
        Mod[t, 1]*2/Ceiling[t] Abs[Sin[(Ceiling[t] #)/2]]] & /@
     Range[0, 2 Pi, Pi/nn]}


   },
  PlotRange -> {{-3.1, 1.7}, {-2.7, 2.7}},
  Frame -> False, ImageSize -> 400, Background -> Black

  ], {{nn, 16}, {4, 8, 16, 32, 64}, ControlPlacement -> Top,
  ControlType -> Setter}, {t, 1, 12, ControlPlacement -> Right,
  ControlType -> VerticalSlider}]
```
The last animation positioned horizontally:

Place the cursor over the image to start the animation.
In this item I will demonstrate a smooth transition from the standard cardioid determined by the family of circles that it envelopes into the unit circle involute, also determined by the family of circles that it envelopes.

The animation below starts from the classical cardioid and transitions to the circle involute and loops back to the cardioid.

Place the cursor over the image to start the animation.

Thursday, May 23, 2024

Today I created the notebook 20240523_A2P3_cardioid.nb in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook. This notebook relates to Problem 3 on Assignment 2. In this file, I demonstrated how to create a cardioid in Mathematica. Please pay attention to how I use pure functions to create many points, and many circles. Today, at the beginning of the class, I modified the notebook of Tuesday class 20240521_A2P3_circle_involute.nb which is in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook.

Wednesday, May 22, 2024

We previously discussed a highly useful concept in Mathematica: the pure function. In my code, pay attention to the occurrences of pure functions and how I use them to create many lines or many points or many circles.

Pure Function. In earlier exercises, we often assigned a name to a function for further use. However, this approach is not always practical. Mathematica allows us to use functions as if they were named without actually naming them. For example, the square function is not explicitly named in Mathematica, but we can calculate the square of 7 by writing (#^2)&[7]. In this case, we use (#^2)& as a reference to the square function. Instead of explicitly naming the argument, we use a placeholder #, and we conclude the definition with &.

Notice that, instead of explicitly naming the argument (independent variable), in a pure function we use # which is called a slot in Mathematica. It acts as a placeholder for the argument that will be passed to the function. The symbol & is called function operator in Mathematica. It indicates the end of a pure function definition. For example, in the pure function (#^2)& the expression (#^2) defines the function, and ampersand & marks the end of the function.

The full potential of a pure function is realized when combined with the Map[] command. For instance, Map[(#^2)&,{a,b,c}] yields {a^2,b^2,c^2}. Thus, Map[] applies the specified function to each member of the given list. An alternative shortcut form for Map[] is /@. Using this shortcut, the previous example becomes (#^2)&/@{a,b,c}. This approach is extremely beneficial when dealing with complex functions and large lists containing hundreds of entries.
In Problem 3 on Assignment 2 you are asked to explore two famous curves cycloid and cardioid. First we discuss the cycloid.
Wikipedia's definition of a Cycoid is: A cycloid is the curve traced by a point on the rim of a circular wheel as the wheel rolls along a straight line without slipping. One could demonstrate a cycloid in a dark room by attaching a small light to a rolling wheel and taking a long exposure photography of the motion. This is what American photographer Berenice Abbott did to create her photograph Cycloid:

You can read more about Berenice Abbott and her art at MoCP and Mount Holyoke College
In this item I will illustrate the derivation of the parametric equations for the cycloid which you need to implement in the animations in Mathematica. In the following derivation the vectors $\mathbf{i}$ and $\mathbf{j}$ are the unit coordinate vectors $\displaystyle \left[\begin{array}{c} 1 \\ 0 \end{array} \right]$ and $\displaystyle \left[\begin{array}{c} 0 \\ 1 \end{array} \right]$, respectively. In Mathematica notation the vector $\mathbf{i}$ is the pair {1,0} and the vector $\mathbf{j}$ is the pair {0,1}.
Let $t\in [0,\pi].$ The position vector of the gray center of the circle in the above pictures is \[ t \, \mathbf{i} + \mathbf{j}. \] If the unit circle was positioned at the origin, then the position vector of the red point on the unit circle would be \[ \bigl(\cos(-t -\pi/2) \bigr) \, \mathbf{i} + \bigl(\sin(-t -\pi/2) \bigr) \mathbf{j} = - (\sin t ) \, \mathbf{i} - (\cos t ) \mathbf{j}. \] Consequently, the position vector of the red point on the unit circle in the above pictures is \[ \bigl( t - \sin t \bigr) \, \mathbf{i} + \bigl(1 - \cos t \bigr) \mathbf{j}. \] In Mathematica notation the vector $\mathbf{i}$ is the pair {1,0} and the vector $\mathbf{j}$ is the pair {0,1}. Thus, the parametric equations of the cycloid in Mathematica notation is (t - Sin[t]) {1,0} + (1 - Cos[t]) {0,1} = {t - Sin[t] , 1 - Cos[t] } The following animation might help you to understand the above derivation.
Place the cursor over the image to start the animation.
In the first part of Problem 2 I ask you to reproduce the following three animations.
Place the cursor over the image to start the animation.

Place the cursor over the image to start the animation.

Place the cursor over the image to start the animation.

In the second part of Problem 2 I ask you to explore the Cardioid.

Here is a derivation of the equation of a cardioid.

Click through several helpful images.

The origin $O = (0,0)$ of the coordinate system is the gray point. Denote by $C$ the black point in the picture.
Both circles in the picture are unit circles, the gray one centered at $O,$ the black one centered at $C.$
The angle at the gray point marked by the blue arc between the green and the blue point measures $t$ radians. That is, the length of this blue arc is $t.$
There are two other angles in the picture which also measure $t$ radians: the angle marked by the blue arc between the blue and the red point and the angle marked by the black arc between the blue point and the purple point.
The green point is $(1,0),$ the blue point is $(\cos t, \sin t),$ the black point $C$ is $(2\cos t, 2\sin t),$ the purple point is $(2\cos t-1, 2\sin t).$
The goal is to determine the coordinates of the red point.
Denote by $\mathbf{a}$ the unit vector whose tail is the black point and whose head is the red point. Based on the previous items we have \begin{align*} \mathbf{a} & = \bigl(\cos( \pi+2 t ) \bigr) \mathbf{i} + \bigl(\sin( \pi+2 t ) \bigr) \mathbf{j} \\ & = -\bigl(\cos(2 t ) \bigr) \mathbf{i} - \bigl(\sin(2 t ) \bigr) \mathbf{j}. \end{align*}
Denote by $\mathbf{c}$ the position vector of the black point. Then the position vector of the red point is \[ \mathbf{c} + \mathbf{a} = \bigl( 2 \cos t - \cos(2 t ) \bigr) \mathbf{i} + \bigl(2 \sin t - \sin(2 t ) \bigr) \mathbf{j}. \]
Thus the parametric equations for this cardioid are \begin{align*} x & = 2 \cos t - \cos(2 t ) \\ y & = 2 \sin t - \sin(2 t ) \end{align*}

In the Cardioid part of Problem 2 on Assignment 2 you need to reproduce two pictures from Wikipidia's Cardioid page I made an animation that unifies these two pictures. You should be able to produce something like the animation below. If not, you can present one animation and one picture.
Place the cursor over the image to start the animation.
Once you have figured out how to construct a cardioid, you should be able to construct Generalized Cardioids. In this part of Problem 2 you are asked to produce some of the generalized cardioids as shown in the animations below. These animated gif files are large. On a slow internet connection it takes a while for them to load.
Below is the cardioid generated by a wheel with radius 1/2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 1/3 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 3/2 rolling on a circle with radius 1.
Place the cursor over the image to start the animation.
For completeness, I post four more generalized cardioids; this is for the optional third part of Problem 2. The animations below are large. On a slow internet connection it takes a while for them to load.
Below is the cardioid generated by a wheel with radius 1/2 rolling inside of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 1/3 rolling inside of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 2 rolling "inside" of a circle with radius 1.
Place the cursor over the image to start the animation.
Below is the cardioid generated by a wheel with radius 3/2 rolling "inside" of a circle with radius 1.
Place the cursor over the image to start the animation.

Tuesday, May 21, 2024

Today in class I created the notebook 20240521_A2P3_circle_involute.nb which is in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook. This notebook relates to Problem 3 on Assignment 2. I will post more about this problem tomorrow.
Today class was online. The recording of the class is on the right.

If the video on the right does not work, try this link for the zoom video with the Passcode: Z2!p3b+b.

PDF printout of the notebook created during the class.
On Monday, I created the notebook 20240520_A2P2_Ramanujan.nb which is in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook. This notebook relates to Problem 2 on Assignment 2.
On Friday, I created the notebook 20240517_A2P1.nb which is in our shared Dropbox directory Dropbox\307_Files\2024. I created a PDF printout of this notebook. This notebook relates to the last part of Problem 1 on Assignment 2.

Thursday, May 16, 2024

The notebook 20240516_A2P1_pure_functions.nb in our shared Dropbox directory Dropbox\307_Files\2024 contains what we discussed today. This file relates to Problem 1 on Assignment 2. In this file, I demonstrated how Mathematica Plot[] can be unreliable to give complete information about a function that we are exploring.
Before discussing problems posted in Assignment 2, we discussed a highly useful concept in Mathematica: the concept of pure function. In the code in 20240516_A2P1_pure_functions.nb, pay attention to occurrences of pure functions in action to create many points on a graph of a function.

Pure Function. In earlier problems, we often assigned a name to a function for further use. However, this approach is not always practical. Mathematica allows us to use functions as if they were named without actually naming them. For example, the square function is not explicitly named in Mathematica, but we can calculate the square of 7 by writing the following code: (#^2)&[7]. In this case, we use (#^2)& as a reference to the square function. Instead of explicitly naming the argument (independent variable), we use # which is called a slot in Mathematica. It acts as a placeholder for the argument that will be passed to the function. The symbol & is called function operator in Mathematica. It indicates the end of a pure function definition. For example, in the pure function (#^2)& the expression (#^2) defines the function, and ampersand & marks the end of the function.

The full potential of a pure function is realized when combined with the Map[] command. For instance, Map[(#^2)&,{a,b,c}] yields {a^2,b^2,c^2}. Thus, Map[] applies the specified function to each member of the given list. An alternative shortcut form for Map[] is /@. Using this shortcut, the previous example becomes (#^2)&/@{a,b,c}. This approach is extremely beneficial when dealing with complex functions and large lists containing hundreds of entries.

Monday, May 13, 2024

Today I created the notebook 20240513_Toroid. You can find it in our shared Dropbox directory \307_Files\2024\. In this notebook I explain how to create cylinders, twisted cylinders, vases, twisted vases, toroid, and twisted toroid.
Below I present two animations which show two ways to construct the one-third-twisted triangular toroid.

In this item, the one-third-twisted triangular toroid is constructed by a rotating equilateral triangle. The triangle is rotated by the full circle, that is the angle $2\pi$.

Place the cursor over the image to start the animation.

The code that is used for the above picture (not the animation) is below:

Show[ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[t, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[t,3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {t, 0,
   3}, {s, 0, 2 Pi}, PlotPoints -> {51, 201},
  PlotStyle -> {Opacity[0.9]}, Mesh -> False, Exclusions -> None,
  PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[0, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[0,
     3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0, 0.75], Thickness[0.006]},
  Exclusions -> None],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[1, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[1, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0.95, 0, 0], Thickness[0.006]},
  Exclusions -> None],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[2, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[2, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   2 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0.85, 0], Thickness[0.006]},
  Exclusions -> None], ImagePadding -> {{0, 0}, {0, 0}},
 Boxed -> True, BoxStyle -> {Opacity[0]}, Axes -> False,
 ImageSize -> 1000, PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}]

The above code uses the functions that we defined earlier:

Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

In this item, the one-third-twisted triangular toroid is constructed by a rotating line segment. The line segment is rotated by the three full circles, that is by the angle $6\pi$.

Place the cursor over the image to start the animation.

The code that is used for the above picture (not the animation) is below:

Show[ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[t, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[t, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {t, 0,
   1}, {s, 0, 6 Pi}, PlotPoints -> {51, 201},
  PlotStyle -> {Opacity[0.9]}, Mesh -> False, Exclusions -> None,
  PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}],
 ParametricPlot3D[
  3 {Cos[s], Sin[s], 0} +
   NgonCos[0, 3] (Cos[s/3] {Cos[s], Sin[s], 0} + Sin[s/3] {0, 0, 1}) +
    NgonSin[0, 3] (-Sin[s/3] {Cos[s], Sin[s], 0} + Cos[s/3] {0, 0, 1}), {s, 0,
   6 Pi}, PlotPoints -> {201},
  PlotStyle -> {RGBColor[0, 0, 0.75], Thickness[0.006]},
  Exclusions -> None], ImagePadding -> {{0, 0}, {0, 0}},
 Boxed -> True, BoxStyle -> {Opacity[0]}, Axes -> False,
 ImageSize -> 1000, PlotRange -> {{-4, 4}, {-4, 4}, {-1.1, 1.1}}]

The above code uses the functions that we defined earlier:

Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

Saturday, May 11, 2024

On Friday, we introduced functions inspired by the trigonometric functions cosine and sine, but designed to draw regular ngons, for example equilateral triangle, square, pentagon, hexagon, heptagon, octagon, nonagon, decagon, hendecagon, dodecagon, and so on. The notebook that I created today you can find in our shared Dropbox directory \307_Files\2024\ under the name 20240510_A1P2.nb.
The most important feature of the functions Cos[t] and Sin[t] is that they provide a parametrization of the unit circle. An animation illustrating this feature was posted on Thursday.
The principle presented in the animation posted on Thursday is the general principle of parametric equations of curves in the plane. Given two functions (one green and one blue) of the same independent variable t, taken as the coordinates of a moving point, then, as the independent variable t changes, the point does trace a curve in the plane.
In the PNG picture below I explain the geometry that is behind the definition of NgonCos[] and NgonSin[] which I defined in class. In the PNG picture below I used the function Mod[t,1]. In class I used the equivalent expression t-Floor[t]. In fact you can check in Mathematica that
```
FullSimplify[Mod[t, 1] == t - Floor[t]]
```
The result of the preceding command is True, meaning that Mathematica recognizing the above identity as correct.

The formulas derived in the preceding item, implemented in Mathematica are as follows:

Clear[NgonCos, NgonSin];
NgonCos[t_, nn_] := (1 - (t - Floor[t])) Cos[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Cos[(2/nn) \[Pi] (1 + Floor[t])];
NgonSin[t_, nn_] := (1 - (t - Floor[t])) Sin[(2/nn) \[Pi] Floor[t]] + (t -
      Floor[t]) Sin[(2/nn) \[Pi] (1 + Floor[t])];

The final product of this work are the graphs of the first nine regular $n$-gons inscribed in the unit circel: the equilateral triangle, the square, and the pentagon, the hexagon, the heptagon, the octagon, the nonagon, the decagon, the hendecagon, the dodecagon, see the Regular Polygon webpage at Wolfram MathWorld.

Thursday, May 9, 2024

Today we introduced functions inspired by the trigonometric functions cosine and sine, but designed to draw regular ngons, for example equilateral triangle, square, pentagon, hexagon, heptagon, octagon, nonagon, decagon, hendecagon, dodecagon, and so on. The notebook that I created today you can find in our shared Dropbox directory \307_Files\2024\ under the name 20240222_ngons.nb.
To appreciate the Beauty of Trigonometry, one needs to understand the most important feature:

The trigonometric functions Cos[t] and Sin[t] provide a parametrization of the unit circle.

The animation below illustrates how this parametrization is obtained.
The main components of the animation are as follows
- The black circle is the unit circle.
- The values of t $\in [0,2\pi]$ are represented by orange lengths. In each scene there are three orange lengths: the horizontal length, the vertical length and the arc length on the unit circle.
- The values of Cos[t] are green horizontal line segments.
- The values of Sin[t] are blue vertical line segments.

Place the cursor over the image to start the animation.

The principle presented above is the general principle of parametric equations of curves in the plane. Given two functions (one green and one blue) of the same independent variable t, taken as the coordinates of a moving point, then, as the independent variable t changes, the point does trace a curve in the plane.

Wednesday, May 8, 2024

In this part of the class we study computational software system Wolfram Mathematica. We will focus on symbolic and numerical calculations, visualization, and programming in Mathematica. But Mathematica is much more than that. To read more about Mathematica see An Elementary Introduction to the Wolfram Language.
The following question naturally arises as we start with the Mathematica portion of this class: Why learn about Mathematica? This is not an easy question. Here are some aspects of Mathematica that make it worth your attention.
- Mathematica is a powerful computational tool that can handle a wide range of mathematical problems, from basic algebra to advanced calculus and beyond.
- Unlike many other mathematical software systems, Mathematica excels in symbolic computation, allowing you to manipulate mathematical expressions and equations symbolically closely resembling mathematical structures and thinking.
- Mathematica provides sophisticated visualization capabilities, enabling you to create compelling graphical representations of your mathematical results.
- Mathematica is a high-level programming language that offers an extensive array of predefined functions, designed to simplify and streamline tasks that are commonly encountered in mathematical and technical computing. My impression is that this makes it more accessible and user-friendly compared to other mathematical software, enabling users to achieve complex objectives with greater ease.
- A lot of help is available on-line, for example Mathematica Stack Exchange, Wolfram Community and ChatGPT is quite good at offering help with Mathematica questions.
- Solving mathematical problems is easier using Mathematica. How so? If a problem involves symbolic manipulations, we can do them in Mathematica exactly; if that approach does not lead to a solution, we can perform numerical approximations, and to guide us toward the process, we can use graphical visualization.
I have enjoyed the interaction between my mind and computers since I first started using them in the early 1990s. Only recently, I encountered a powerful metaphor for the relationship between the mind and computers expressed by Steve Jobs. In an old interview, Steve Jobs illustrated the usefulness of computers with a compelling analogy. He said: "For me, a computer has always been a bicycle for the mind." That is what ChatGPT is. Isn't that wonderful!
See the Bicycle for the Mind video. Or, a longer version.
I am convinced that your mathematical learning experience will be enriched if you engage in mathematical explorations using technology.
I recently encountered a fascinating geometric fact online: Imagine two squares where a vertex of the larger square is positioned at the center of the smaller square. Regardless of how these two squares are positioned, the area of their intersection remains constant. My description might not fully capture the beauty of this fact — indeed, an animation is worth a thousand words. How am I to make an animation? I must use technology. Here is an animation created in Mathematica.

Place the cursor over the image to start the animation.
I should have left it as an exercise for you to figure out why what I claim in the preceding item is true. But, the solution supported by a Mathematica animation might indicate why using technology can be powerful tool in communicating Mathematics.
Place the cursor over the image to start the animation.

Monday, April 1, 2024 (updated on Sunday, May 5, 2024)

The Mathematica part of the class will start on Monday, May 6, 2024 in BH 215 at 2:00 pm.
The information sheet
We will use
To get started with Mathematica see my Mathematica page. Please watch the videos that are on my Mathematica page before the first class. Watching the movies is essential for being able to organize your homework notebooks well! I will not discuss the basics of notebook structuring in class.

Spring 2024
MATH 307: Mathematical computing
with Mathematica

Branko Ćurgus

Spring 2024 MATH 307: Mathematical computing with Mathematica

Branko Ćurgus

Spring 2024
MATH 307: Mathematical computing
with Mathematica